home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib17.dsk / CUSTOM CATALOG.bas < prev    next >
Encoding:
BASIC Source File  |  1990-01-01  |  3.4 KB  |  84 lines
  1. 10  REM  **********************
  2. 20  REM  *   CUSTOM CATALOG   *
  3. 30  REM  *   BY MASON JONES   *
  4. 40  REM  * COPYRIGHT (C) 1983 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * LINCOLN, MA. 01773 *
  7. 70  REM  **********************
  8. 80  REM  ***CATALOG***
  9. 90  TEXT : HOME : PRINT "*********** CUSTOM CATALOG ***********"
  10. 100  PRINT : PRINT  TAB( 13);"BY MASON JONES": POKE 34,4
  11. 110  VTAB 20: PRINT "** COPYRIGHT 1983 BY MICROSPARC, INC. **": VTAB 6: INVERSE : HTAB 14: PRINT "CATALOG MENU"
  12. 120  NORMAL 
  13. 130  PRINT : PRINT "1] CHANGE HEADING";
  14. 140  PRINT  TAB( 20);"2] CHANGE LOCK SYMBOL"
  15. 150  PRINT "3] CHANGE TYPE";
  16. 160  PRINT  TAB( 20);"4] CHANGE SIZES"
  17. 170  PRINT 
  18. 180  PRINT "5] CHANGE NAMES";
  19. 190  PRINT  TAB( 20);"6] QUIT"
  20. 200 CH =  PEEK( -16384)
  21. 210  IF CH >175  AND CH <183  THEN 230
  22. 220  GOTO 200
  23. 230  POKE  -16368,0
  24. 240  IF CH = 176  THEN  TEXT : HOME : END 
  25. 250  IF CH = 177  THEN 310
  26. 260  IF CH = 178  THEN 430
  27. 270  IF CH = 179  THEN 520
  28. 280  IF CH = 180  THEN 670
  29. 290  IF CH = 181  THEN 750
  30. 300  IF CH = 182  THEN  END 
  31. 310  HOME : PRINT 
  32. 320  PRINT "WHEN ASKED, PLEASE INPUT THE HEADING"
  33. 330  PRINT : PRINT "YOU WISH TO BE SHOWN WHEN THE DISK"
  34. 340  PRINT : PRINT "IS CATALOGED. PLEASE DO NOT INPUT"
  35. 350  PRINT : PRINT "MORE THAN 12 CHARACTERS, OR IT MAY"
  36. 360  PRINT : PRINT "NOT WORK PROPERLY."
  37. 370  PRINT 
  38. 380  INPUT "HEADING: ";HD$
  39. 390  IF HD$ =  CHR$(17)  THEN 820: REM  CTL-Q
  40. 400  IF  LEN(HD$) <12  THEN HD$ = HD$ +" ": GOTO 400
  41. 410  FOR X = 1 TO  LEN(HD$):H1$ =  MID$ (HD$,X,1): POKE 46011 -X,( ASC(H1$) +128): NEXT X
  42. 420  GOTO 820
  43. 430  HOME : PRINT 
  44. 440  PRINT "WHEN ASKED, INPUT THE SYMBOL YOU WANT"
  45. 450  PRINT : PRINT "TO TAKE THE PLACE OF THE ASTERISK": PRINT 
  46. 460  PRINT "FOR DENOTING A LOCKED FILE IN THE": PRINT 
  47. 470  PRINT "CATALOG OF THE DISK. YOU MUST INPUT": PRINT : PRINT "ASCII CODE OF THE CHARACTER": PRINT : PRINT "WITH THE HIGH BIT SET.": PRINT 
  48. 480  PRINT : INPUT "SYMBOL'S ASCII CODE: ";SY$: IF SY$ =  CHR$(17)  THEN 820: REM  CTL-Q
  49. 490 SY =  VAL(SY$)
  50. 500  POKE 44515,SY
  51. 510  GOTO 820
  52. 520  HOME : PRINT 
  53. 530  PRINT "WHEN ASKED, INPUT ASCII CODE (HIGH ": PRINT 
  54. 540  PRINT "BIT SET) OF THE SYMBOL YOU WANT TO STAND"
  55. 550  PRINT "FOR THE FILE TYPE MENTIONED. SIMPLY": PRINT 
  56. 560  PRINT "PRESS <RETURN> TO PASS.": PRINT 
  57. 570  PRINT : POKE 34,14
  58. 580  HOME : INPUT "APPLESOFT FILE: ";AF$:AF =  VAL(AF$)
  59. 590  HOME : INPUT "INTEGER FILE: ";IN$:IN =  VAL(IN$)
  60. 600  HOME : INPUT "BINARY FILE: ";BF$:BF =  VAL(BF$)
  61. 610  HOME : INPUT "TEXT FILE: ";TF$:TF =  VAL(TF$)
  62. 620  IF AF$ < >""  THEN  POKE 45993,AF
  63. 630  IF IN$ < >""  THEN  POKE 45992,IN
  64. 640  IF BF$ < >""  THEN  POKE 45994,BF
  65. 650  IF TF$ < >""  THEN  POKE 45991,TF
  66. 660  GOTO 820
  67. 670  HOME : PRINT 
  68. 680  PRINT "YOU CAN EITHER:": PRINT 
  69. 690  PRINT "   1) MAKE SIZES 000"
  70. 700  PRINT "   2) HAVE NO SIZES PRINTED"
  71. 710  PRINT : PRINT "   CHOICE: ";: GET CH$: PRINT CH$:CH =  VAL(CH$)
  72. 720  IF CH = 1  THEN  POKE 44615,169: POKE 44616,0
  73. 730  IF CH = 2  THEN  FOR X = 44643 TO 44645: POKE X,234: NEXT X
  74. 740  GOTO 820
  75. 750  HOME : PRINT 
  76. 760  PRINT "YOU CAN EITHER:": PRINT 
  77. 770  PRINT "   1) HAVE NO NAMES PRINTED"
  78. 780  PRINT "   2) HAVE NAMES SCRAMBLED"
  79. 790  PRINT : PRINT "   CHOICE: ";: GET CH$: PRINT CH$:CH =  VAL(CH$)
  80. 800  IF CH = 1  THEN  FOR X = 44571 TO 44573: POKE X,234: NEXT X
  81. 810  IF CH = 2  THEN  POKE 44542,32: POKE 44543,72: POKE 44544,249
  82. 820  TEXT : HOME : VTAB 12: PRINT "ANY FURTHER CATALOG REFINEMENTS? ";
  83. 830  GET B$: PRINT B$: IF B$ = "Y"  THEN 80
  84. 840  HOME : PRINT  CHR$(4);"CATALOG": END